kernel/arch/x86/linker-script

   1 ENTRY(_start)
   2 PHDRS
   3 {
   4         all PT_LOAD FILEHDR PHDRS AT (0x80200000);
   5 }
   6 SECTIONS
   7 {
   8         . = 0x80200000 + SIZEOF_HEADERS;
   9         .text : {
  10                 *(.text)        *(.gnu.linkonce.t.*)
  11                 *(.rodata*) *(.gnu.linkonce.r.*)
  12                 . = (. + 3) & ~ 3;
  13                 eh_frame_begin = .;
  14                 *(.eh_frame)
  15                 LONG(0)
  16                 *(.rela.eh_frame) *(.gcc_except_table)
  17                 . = (. + 3) & ~ 3;
  18                 ctors = .;
  19                 *(.ctors)
  20                 LONG(0)
  21                 ctors_end = .;
  22                 *(.irqs)
  23         } :all
  24         . = (. + 0xfff) & ~ 0xfff;
  25         roshared_start = .;
  26         .roshared : { *(.roshared) } :all
  27         roshared_end = .;
  28         . = . | 0xfff;
  29         roshared_page_end = .;
  30         . = . + 1;
  31         rwshared_start = .;
  32         .shared_data : { *(.rwshared) } :all
  33         rwshared_end = .;
  34         . = . | 0xfff;
  35         rwshared_page_end = .;
  36         . = . + 1;
  37         data_start = .;
  38         .data : { *(.data) *(.gnu.linkonce.d.*)  } :all
  39         bss_start = .;
  40         .bss : { *(.bss) } :all
  41         bss_end = .;
  42         _end = .;
  43 }